エクセルマクロ オンライン講座コメント紹介

コメント紹介
   └ エクセルマクロVBA「Web連携」
       └ エクセルマクロVBA「Web連携」Microsoft Internet Controls_Webコンテンツの取得

エクセルマクロVBA「Web連携」Microsoft Internet Controls_Webコンテンツの取得

[11313] 2019-04-03 13:24:33 ざきさんさんからの投稿です。

返信ありがとうございます。
アプリという表現が正しかったのかわかりませんが、サイト上で顧客管理をしています。ここでURLをさらしていいのかわからなかったので、添付ファイルにて、URLを送ります。

 


[11317] 2019-04-08 09:25:48 小川慶一さんからの投稿です。

ざきさんさん:

すいません、いただいたコメント、今気づきました。
BASIC認証かかっていますね。

以下のサンプルを参考にしてください。
(同様の認証がかかっているウチの秘密サイトで動作確認済です)

Option Explicit

'required:
'microsoft xml 6,0.
'microsoft html object library
'micrsoft internet controls

'必要事項:
'[1] Base64エンコードされたid, passwordの文字列を生成する
'[2] [1]をリクエスト時のヘッダー情報に含める
'[3] リクエストを実行する
Sub BasicCertificationLogin()
    Dim sId As String   '認証id
    Dim sPass As String '認証pass
    Dim sEnc As String  'base64エンコード済id:pass文字列
    sId = "myid"
    sPass = "mypass"
    sEnc = EncodeBase64(sId & ":" & sPass) '[1]
    
    Dim sHead As String
    sHead = "Authorization: Basic " & sEnc & vbCrLf  '[2]
    
    Dim url As String
    url = "http://foo.bar/";
    
    Dim objIE As New InternetExplorer
    objIE.Visible = True
    
    objIE.navigate url, , , , sHead '[3]
End Sub
Function EncodeBase64(st As String) As String
  Dim arrData() As Byte
  arrData = StrConv(st, vbFromUnicode)

  Dim objXML As MSXML2.DOMDocument60
  Dim objNode As MSXML2.IXMLDOMElement

  Set objXML = New MSXML2.DOMDocument60
  Set objNode = objXML.createElement("b64")

  objNode.DataType = "bin.base64"
  objNode.nodeTypedValue = arrData
  EncodeBase64 = objNode.text

  Set objNode = Nothing
  Set objXML = Nothing
End Function



> 返信ありがとうございます。
> アプリという表現が正しかったのかわかりませんが、サイト上で顧客管理をしています。ここでURLをさらしていいのかわからなかったので、添付ファイルにて、URLを送ります。

 


まずはここから!スマホでも学べる無料動画講座

今なら先着30名限定で無料!定価4,800円の、初心者のためのエクセルマクロ動画講座。
  1. Excel 97~Excel 2016まですべて対応。動画本数20本、総再生時間2時間44分53秒
  2. PC, Mac, iPhone, iPad, Androidのお好みの環境で、いつでも好きなときに学べます。
2004年から10年間述べ3,000名以上に実施した研修の経験と実績を集約した講座です。
いますぐ無料で試してください。

トップへ